roWebSocketEvent

During an open WebSocket connection, the roWebSocket object generates multiple asynchronous WebSocket events that are delivered as roWebSocketEvent objects via the object's message port. The roWebSocket sends the roWebSocketEvent with the following predicates that indicate its valid event types:

• GetType() as Int
• GetSocketId() as Int
• GetSocketData() as Dynamic
• GetInfo() as Object

GetType() as Int

Description

Returns the event type of the WebSocket event.

Event types

Return Value

The event type value.

Example

sub Setup()
'Sets event constants like: m.OpenEvent = 1, m.ClosedEvent = 2, …
SetWSEventConstants(m)
end sub

sub CreateWebSocket(url as String)
	m.websocket = createObject("roWebSocket")
	m.port = createObject("roMessagePort")
    m.websocket.setMessagePort(m.port)
    ' Set Url
    m.websocket.SetUrl(url)
	print "Opening connection..."
    m.websocket.Open()
end sub

sub HandleWSEvent(msg as Object)
	if msg.GetType()= m.OpenEvent ' = 1
		print "WebSocket opened."
		' Sending a text message after opening.
		m.websocket.Send("Client ready")
	end if
end sub

GetSocketId() as Int

Description

Returns a unique number for the WebSocket instance that originated the event.

Return Value

The WebSocket identifier.

Example

sub Setup()
	m.webSockets = {} ' Creating pool of WebSockets
 	 m.port = createObject("roMessagePort")
	'Sets event constants like: m.OpenEvent = 1, m.ClosedEvent = 2, …
	SetWSEventConstants(m)
end sub

sub CreateWebSocket(url as String)
	websocket = createObject("roWebSocket")
    websocket.setMessagePort(m.port)
    ' Set Url
    websocket.SetUrl(m.top.testUrl)
    ' Add socket to the pool using socket id string value as a key
    m.webSockets.AddReplace(websocket.GetSocketId().toStr(), websocket)
	print "Opening connection..."
    websocket.Open()
end sub

sub HandleWSEvent(msg as Object)
event = msg.GetType()
	if event = m.CloseEvent ' = 2
		socket_id = msg.GetSocketId().ToStr()
		m.webSockets.Delete(socket_id)
	end if
end sub

GetSocketData() as Dynamic

Description

Returns the socket data object stored in the WebSocket instance that originated the event. The socket data object is set with the roWebSocket.SetData() method.

Return Value

The socket data object.

Example

websocket = createObject("roWebSocket")
websocket.setMessagePort(m.port)
' Set Url
websocket.SetUrl(ws_url)
' Socket data - it will be available in WebSocket events via GetSocketData()
' The socket data can be any Object type.
' Setting associative array in socket data.
data = {
     Data1 : 239,
     Data2 : "DataValue2"
}
websocket.SetData(data)
' Setting integer value in socket data.
websocket.SetData(239)
' Setting string value in socket data.
websocket.SetData("Some text")
' "Tracing" function taking event object and printing the socket data.
sub TraceSocketData(msg as Object)
    data = msg.GetSocketData()
    if data <> invalid
        print "Socket data: "; data
    end if
end sub

GetInfo() as Object

Description

Returns an associative array with event-specific information.

Return Value

The event-info associative array.

Event-specific fields

Opened event (type: 1)

Closed event (type: 2)

Error event (type: 3)

MsgSent event (type: 4)

TextReceived event (type: 5)

DataReceived event (type: 6)

PingReceived event (type: 7)

PongReceived event (type: 8)

Timer event (type: 9)

Example

sub Setup()
'Sets event constants like: m.OpenEvent = 1, m.ClosedEvent = 2, …
SetWSEventConstants(m)
end sub

sub CreateWebSocket(url as String)
m.websocket = createObject("roWebSocket")
m.port = createObject("roMessagePort")
    m.websocket.setMessagePort(m.port)
    ' Set Url
    m.websocket.SetUrl(url)
  
print "Opening connection..."
    m.websocket.Open()
end sub

sub TraceOpenEvent(msg as Object)
    ' Open info
    info = msg.GetInfo()
    print "Protocol="; info.Protocol
    print "TargetIPaddr="; info.targetIPAddr
    print "effectiveUrl="; info.effectiveUrl
    ' Socket Data
    TraceSocketData(msg)
end sub

sub TraceCloseEvent(msg as Object)
    ' Close info
    info = msg.GetInfo()    
    print "code="; StrI(info.Code); ", reason="; info.Reason
    print "error="; StrI(info.Error); ", err_msg="; info.ErrorMsg
    ' Socket Data
    TraceSocketData(msg)
end sub

sub TraceSocketData(msg as Object)
    data = msg.GetSocketData()
    if data <> invalid
        print "Socket data: "; data
    end if
end sub

sub HandleWSEvent(msg as Object)
	if msg.GetType()= m.OpenEvent ' = 1
		print "WebSocket opened."
		' Tracing Opened event information.
		TraceOpenEvent(msg)
		' Sending a text message after opening.
		m.websocket.Send("Client ready")
	else if msg.GetType()= m.ClosedEvent ' = 2
		print "WebSocket closed."
		' Tracing Closed event information.
		TraceCloseEvent(msg)
	end if
end sub